日本語

クロージャ

関数を値として扱う

🍇 引数 ➡️ 戻り値の型 … 🍉 で、名前のない関数(クロージャ)を作れます。変数に入れたり、引数として渡したりできます。呼ぶときは ⁉️ クロージャ 引数❗️ です。

Emojicode
🏁 🍇
  🍇 x 🔢 ➡️ 🔢
    ↩️ x ✖️ 2
  🍉 ➡️ double

  😀 🔡 ⁉️ double 21❗️❗️❗️
🍉
出力
42

クロージャの型は 🍇引数の型 ➡️ 戻り値の型🍉 と書きます。上の double の型は 🍇🔢➡️🔢🍉 です。

引数として渡す

クロージャを受け取るメソッドを作ると、「何をするか」を呼ぶ側が決められます。

Emojicode
🐇 🧮 🍇
  🐇❗️ 🎡 f 🍇🔢➡️🔢🍉 times 🔢 start 🔢 ➡️ 🔢 🍇
    start ➡️ 🖍🆕 value
    🔂 i 🆕⏩ 0 times❗️ 🍇
      ⁉️ f value❗️ ➡️ 🖍value
    🍉
    ↩️ value
  🍉
🍉

🏁 🍇
  😀 🔡 🎡🐇🧮 🍇 x 🔢 ➡️ 🔢 ↩️ x ✖️ 2 🍉 10 1❗️❗️❗️
  😀 🔡 🎡🐇🧮 🍇 x 🔢 ➡️ 🔢 ↩️ x ➕ 3 🍉 4 0❗️❗️❗️
🍉
出力
1024
12

リストの並べ替え(🦁)や変換(🐰)も、この形でクロージャを受け取ります(リストと辞書)。

外の変数を使う(キャプチャ)

クロージャの中からは、作った場所の変数を使えます。

Emojicode
🏁 🍇
  🔤こんにちは🔤 ➡️ greeting
  🍇 name 🔡 ➡️ 🔡
    ↩️ 🔤🧲greeting🧲、🧲name🧲!🔤
  🍉 ➡️ greet

  😀 ⁉️ greet 🔤えもじ🔤❗️❗️
🍉
出力
こんにちは、えもじ!

外に持ち出すクロージャ(🎍🥡)

クロージャを戻り値にしたり、インスタンス変数にしまったりして、作った場所より長く使うときは、🍇🎍🥡 のように 🎍🥡 をつけます。

Emojicode
🐇 🏭 🍇
  🐇❗️ 🎛 factor 🔢 ➡️ 🍇🔢➡️🔢🍉 🍇
    ↩️ 🍇🎍🥡 x 🔢 ➡️ 🔢
      ↩️ x ✖️ factor
    🍉
  🍉
🍉

🏁 🍇
  🎛🐇🏭 3❗️ ➡️ triple
  😀 🔡 ⁉️ triple 5❗️❗️❗️
🍉
出力
15

インスタンス変数にしまうときも同じで、渡すクロージャを 🍇🎍🥡 で作ります。しまったクロージャは、あとから ⁉️ で呼べます。

Emojicode
🐇 🔔 🍇
  🖍🆕 onRing 🍇🍉

  🆕 callback 🍇🍉 🍇
    callback ➡️ 🖍onRing
  🍉

  ❗️ 🛎 🍇
    ⁉️ onRing❗️
  🍉
🍉

🏁 🍇
  🆕🔔 🍇🎍🥡
    😀 🔤チリン🔤❗️
  🍉❗️ ➡️ bell
  🛎 bell❗️
  🛎 bell❗️
🍉
出力
チリン
チリン

🎍🥡 をつけ忘れて外に持ち出そうとすると、コンパイルエラーになります。

コンパイルエラーになる例
🐇 🏭 🍇
  🐇❗️ 🎛 factor 🔢 ➡️ 🍇🔢➡️🔢🍉 🍇
    ↩️ 🍇 x 🔢 ➡️ 🔢
      ↩️ x ✖️ factor
    🍉
  🍉
🍉

🏁 🍇
  🎛🐇🏭 3❗️ ➡️ triple
🍉